#include <Servo.h> 
#include <Wire.h>
#include <Bridge.h>
#include <YunServer.h>
#include <YunClient.h>
#include <Process.h>
#include <FileIO.h>

#define ADDRESS             0x68     // Address of TPA81
#define SOFTREG             0x00     // Byte for software version
#define AMBIANT             0x01     // Byte for ambiant temperature
#define WIDTH 36
#define ANG 180/WIDTH

Servo myservo;
int pos = 0; 
int inc = 1;
int temperature[WIDTH][8]; 

YunServer server;

String startString;
int servo_active=1;
int servo_speed=100;
int done=0;
int max_temperature=50;
String mail_address="dexmac221@gmail.com";
int temp_alarm=0;

void write_config(){ 
  File settings = FileSystem.open("/root/config.ini", FILE_WRITE);
  if(settings!=NULL)
  {
    settings.print(mail_address);
    settings.print("\n");
    settings.print(max_temperature);
    settings.print("\n");
    settings.print(servo_active);
    settings.print("\n");
    settings.print(servo_speed);
    settings.print("\n");
    settings.close();
  }
}

void setup() { 
  Wire.begin();
  delay(100);
  myservo.attach(5);  // attaches the servo on pin 5 to the servo object 
  myservo.write(pos*10);
  pinMode(13, OUTPUT);
  digitalWrite(13, LOW);
  Bridge.begin();
  digitalWrite(13, HIGH);
  server.listenOnLocalhost();
  server.begin();
  for(int i=0;i<WIDTH;i++){
    for(int j=0;j<8;j++){
        temperature[i][j]=0;
      }
    }
  FileSystem.begin();
  
  File settings = FileSystem.open("/root/config.ini", FILE_READ);
  
  if(settings!=NULL)
  {
    char mail_addr[256];
    int counter=0;
    char c='\0';
    do{
      c = settings.read();
      mail_addr[counter]=c;
      counter++;
    } while(c!='\n');
    
    mail_addr[counter-1]='\0';
    
    mail_address=String(mail_addr);
    
    String tmp_str; 
    do{
      c = settings.read();
      tmp_str += c;
    } while(c!='\n');
    
    max_temperature=tmp_str.toInt();
    tmp_str="";
    
    do{
      c = settings.read();
      tmp_str += c;
    } while(c!='\n');
    
    servo_active=tmp_str.toInt();
    tmp_str="";
    
    do{
      c = settings.read();
      tmp_str += c;
    } while(c!='\n');
    
    servo_speed=tmp_str.toInt();
    tmp_str="";
  }
  
  settings.close();
} 
 
void loop() {  
  YunClient client = server.accept();
  
  if (client) {
  
    String command = client.readStringUntil('/');
    command.trim();        //kill whitespace

    if (command == "temperature"){ //arduino/temperature/0
      for(int j=0;j<8;j++){
        for(int i=0;i<WIDTH;i++){
          client.print(temperature[i][j]);
          client.print(" ");
        }
        client.println("");
       }  
     }
     
    if(command=="servo"){ //arduino/servo/0
      servo_active = client.parseInt();
      write_config();
    }
    
    if(command=="speed"){ //arduino/speed/100
      servo_speed = client.parseInt();
      write_config();
    }
    
    if(command=="pos"){ //arduino/pos/100
      myservo.write(client.parseInt());
    }
    
    if(command=="mt"){ //arduino/mt/100
      max_temperature=client.parseInt();
      write_config();
    }
    
    if(command=="mail"){ //arduino/mail/user@gmail.com
      mail_address=client.readString();
      write_config();
    }

    client.stop();
  }
   
  //read sensor data
  for(int i = 0; i < 8; i++){                            // Loops and stores temperature data in array
    temperature[pos][i] = getData(i+2);
    if (temperature[pos][i]>max_temperature){
        Process p;
        String cmd  = "echo 'Alarm' | mutt -s 'Temperature Alarm : "+String(temperature[pos][i])+"C' -- "+mail_address; 
        p.runShellCommand(cmd);
      }
  }
  
  if(servo_active){
    myservo.write(ANG*(pos+1));
  }
  
  pos++;
 
  if(pos==WIDTH){
    pos=0;
    if(servo_active){
        myservo.write(0);
        delay(1000);
    }
  }
  
  delay(servo_speed); 
} 

byte getData(byte reg){                                   // Function to receive one byte of data from TPA81
  Wire.beginTransmission(ADDRESS);                        // Begin communication with TPA81
  Wire.write(reg);                                        // Send reg to TPA81
  Wire.endTransmission();
  Wire.requestFrom(ADDRESS, 1);                           // Request 1 byte
  while(Wire.available() < 1);                            // Wait for byte to arrive
  byte data = Wire.read();                                // Get byte
  return(data);                                           // return byte
}